Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "../base/TokenOperatableTemplateContract.sol";
import "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";

contract SimpleShop is TokenOperatableTemplateContract
{
    using Math for uint256;
    using ERC165Checker for address;

    struct Product {
        address token_address;
        uint256 token_id;
        bool as_multitoken;
    }

    mapping(uint256 => Product) private products;
    mapping(uint256 => uint256) private availables;

    uint256 private _productIds;

    event OnProductDefined(uint256 indexed product_id,Product product);
    event OnProductUpdated(uint256 indexed product_id,Product product);
    event OnProductPurchased(uint256 indexed product_id,Product product,uint256 amount);

    constructor(string memory name_,string memory description_) TokenOperatableTemplateContract(name_,description_) {
        
    }
   
    function get_last_template_id() public view virtual override returns (uint256) {return _productIds;}
    
    function onUndefineTemplate(uint256 product_id) internal virtual override{
        delete products[product_id];
    }
    function define_product(string memory name,string memory desc,address token_address,uint256 token_id,uint256 price,bool start_enabled,address merchant,address currency,uint256 initial_stock) 
        external onlyOwner returns (uint256){

        require(bytes(name).length > 0,"NO_PRD_NAME");        
        
        (bool result,uint256 prd_id) = _productIds.tryAdd(1);
        require(result,"TPL_ID_OVERFLOW");
        _productIds = prd_id;
        
        _fill_template_metadata(prd_id,name,desc,price,start_enabled,merchant,currency);
        bool as_multitoken = _check_product_token(token_address,token_id);

        products[prd_id] = Product(token_address,token_id,as_multitoken);
        availables[prd_id] = initial_stock;
        emit OnProductDefined(prd_id, products[prd_id]);
        return prd_id;
    }
    function udpate_template_product(uint256 product_id,address token_address,uint256 token_id) external onlyOwner {
       
        require(is_defined(product_id),"NO_PRD_DEFINED");
        bool as_multitoken = _check_product_token(token_address,token_id);
        products[product_id] = Product(token_address,token_id,as_multitoken);
        emit OnProductUpdated(product_id,products[product_id]);
    }

    function get_product(uint256 product_id) external view returns (address,uint256,bool){
        Product memory prd = products[product_id];
        return (prd.token_address,prd.token_id,prd.as_multitoken);
    }
    function _check_product_token(address token_address,uint256 token_id) internal view returns(bool){
        bool is_erc1155 = _is_operatable_erc1155(token_address);
        bool is_erc721 = _is_operatable_erc721(token_address);
        require(is_erc1155 || is_erc721,"O_BAD_TOKEN");
        if(is_erc1155){
            IOperatableERC1155Token asErc1155 = IOperatableERC1155Token(token_address);
            require(asErc1155.isTokenDefined(token_id),"NO_TOKEN_ID");
        }
        return is_erc1155;
    }
    function _check_valid(uint256 prd_id) internal view {
       Product memory prd = products[prd_id];
       if(prd.as_multitoken){
            IOperatableERC1155Token asErc1155 = IOperatableERC1155Token(prd.token_address);
            require(asErc1155.isTokenDefined(prd.token_id),"NO_TOKEN_ID");
        }       
    }
    function get_available(uint256 product_id) public view returns (uint256) {
        return availables[product_id];
    }
    function refill_stock(uint256 product_id,uint256 add_amount) external onlyOperator {
        (bool result,uint256 newAvailable) = availables[product_id].tryAdd(add_amount);
        require(result,"STOCK_OVERFLOW");
        availables[product_id] = newAvailable;
    }
    function purchase(uint256 product_id,uint256 amount) external payable{
       require((amount > 0),"ZERO_APPLY_COUNT");
       require(is_enabled(product_id),"PRD_NOT_ONSALE");
       require(availables[product_id] >= amount,"OUT_OF_STOCK");

       _check_valid(product_id);

       Product memory product = products[product_id];
       if(product.as_multitoken)
       {
           IOperatableERC1155Token asErc1155 = IOperatableERC1155Token(product.token_address);
           asErc1155.mintNFTFor(msg.sender, product.token_id,amount);       
       }
       else
       {
           IOperatableERC721Token asErc721 = IOperatableERC721Token(product.token_address);
           asErc721.mintNFTsFor(msg.sender, amount);
       }

       consume_operation_cost(product_id,amount);

       (bool result,uint256 remain) = availables[product_id].trySub(amount);
       require(result,"REMIN_UNDERFLOW");
       availables[product_id] = remain;
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165Checker.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Library used to query support of an interface declared via {IERC165}.
 *
 * Note that these functions return the actual result of the query: they do not
 * `revert` if an interface is not supported. It is up to the caller to decide
 * what to do in these cases.
 */
library ERC165Checker {
    // As per the EIP-165 spec, no interface should ever match 0xffffffff
    bytes4 private constant INTERFACE_ID_INVALID = 0xffffffff;

    /**
     * @dev Returns true if `account` supports the {IERC165} interface.
     */
    function supportsERC165(address account) internal view returns (bool) {
        // Any contract that implements ERC165 must explicitly indicate support of
        // InterfaceId_ERC165 and explicitly indicate non-support of InterfaceId_Invalid
        return
            supportsERC165InterfaceUnchecked(account, type(IERC165).interfaceId) &&
            !supportsERC165InterfaceUnchecked(account, INTERFACE_ID_INVALID);
    }

    /**
     * @dev Returns true if `account` supports the interface defined by
     * `interfaceId`. Support for {IERC165} itself is queried automatically.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsInterface(address account, bytes4 interfaceId) internal view returns (bool) {
        // query support of both ERC165 as per the spec and support of _interfaceId
        return supportsERC165(account) && supportsERC165InterfaceUnchecked(account, interfaceId);
    }

    /**
     * @dev Returns a boolean array where each value corresponds to the
     * interfaces passed in and whether they're supported or not. This allows
     * you to batch check interfaces for a contract where your expectation
     * is that some interfaces may not be supported.
     *
     * See {IERC165-supportsInterface}.
     */
    function getSupportedInterfaces(
        address account,
        bytes4[] memory interfaceIds
    ) internal view returns (bool[] memory) {
        // an array of booleans corresponding to interfaceIds and whether they're supported or not
        bool[] memory interfaceIdsSupported = new bool[](interfaceIds.length);

        // query support of ERC165 itself
        if (supportsERC165(account)) {
            // query support of each interface in interfaceIds
            for (uint256 i = 0; i < interfaceIds.length; i++) {
                interfaceIdsSupported[i] = supportsERC165InterfaceUnchecked(account, interfaceIds[i]);
            }
        }

        return interfaceIdsSupported;
    }

    /**
     * @dev Returns true if `account` supports all the interfaces defined in
     * `interfaceIds`. Support for {IERC165} itself is queried automatically.
     *
     * Batch-querying can lead to gas savings by skipping repeated checks for
     * {IERC165} support.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsAllInterfaces(address account, bytes4[] memory interfaceIds) internal view returns (bool) {
        // query support of ERC165 itself
        if (!supportsERC165(account)) {
            return false;
        }

        // query support of each interface in interfaceIds
        for (uint256 i = 0; i < interfaceIds.length; i++) {
            if (!supportsERC165InterfaceUnchecked(account, interfaceIds[i])) {
                return false;
            }
        }

        // all interfaces supported
        return true;
    }

    /**
     * @notice Query if a contract implements an interface, does not check ERC165 support
     * @param account The address of the contract to query for support of an interface
     * @param interfaceId The interface identifier, as specified in ERC-165
     * @return true if the contract at account indicates support of the interface with
     * identifier interfaceId, false otherwise
     * @dev Assumes that account contains a contract that supports ERC165, otherwise
     * the behavior of this method is undefined. This precondition can be checked
     * with {supportsERC165}.
     *
     * Some precompiled contracts will falsely indicate support for a given interface, so caution
     * should be exercised when using this function.
     *
     * Interface identification is specified in ERC-165.
     */
    function supportsERC165InterfaceUnchecked(address account, bytes4 interfaceId) internal view returns (bool) {
        // prepare call
        bytes memory encodedParams = abi.encodeCall(IERC165.supportsInterface, (interfaceId));

        // perform static call
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly {
            success := staticcall(30000, account, add(encodedParams, 0x20), mload(encodedParams), 0x00, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0x00)
        }

        return success && returnSize >= 0x20 && returnValue > 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

interface IOperatableERC1155Token {

     //Get Contract Level metadata uri - See https://docs.opensea.io/docs/contract-level-metadata
    function contractURI() external view returns (string memory);
    
    //Set Contract Level metadata uri - See https://docs.opensea.io/docs/contract-level-metadata
    function setContractURI(string memory contractURI_) external;

    function lastTokenIds() external view returns (uint256);
    
    //Return token ids and amount.
    function ownedTokenOf(address _addr) external view returns(uint256[] memory,uint256[] memory);

    function canMintForAmount(uint256 tokenId,uint256 tokmentAmount) external view returns(bool);

    function canMintBulkForAmount(uint256[] memory tokenIds,uint256[] memory tokmentAmounts) external view returns(bool);
    
    //Mint nft for some user by contact owner. use for bleeding/crafting or mint NFT from App
    function mintNFTsFor(address _addr,uint256[] memory tokenIds,uint256[] memory amounts) external;

    //Burn nft for some user by contact owner. use for crafting or burn NFT from App
    function burnNFTsFor(address _addr,uint256[] memory tokenIds,uint256[] memory amounts) external;

    //Mint nft for some user by contact owner. use for bleeding/crafting or mint NFT from App
    function mintNFTFor(address _addr,uint256 tokenId,uint256 amount) external;

    //Burn nft for some user by contact owner. use for crafting or burn NFT from App
    function burnNFTFor(address _addr,uint256 tokenId,uint256 amount) external;

    //Get total supply of Token
    function totalSupply(uint256 tokenId) external view returns(uint256);

    //Token id is defined or not
    function isTokenDefined(uint256 token_id) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

/**
 * @dev Interface of use for all of ScrewUp NFT token.
 */
interface IOperatableERC721Token {
   
    //Get Contract Level metadata uri - See https://docs.opensea.io/docs/contract-level-metadata
    function contractURI() external view returns (string memory);
    
    //Set Contract Level metadata uri - See https://docs.opensea.io/docs/contract-level-metadata
    function setContractURI(string memory contractURI_) external;

    //Get all of items for address.
    function ownedTokenOf(address _addr) external view returns (uint256[] memory);

    //Check address is really own item.
    function isOwnedToken(address _addr,uint256 tokenId) external view returns(bool);

    //Update token URI for token Id
    function updateTokenURI(uint256 tokenId,string memory tokenURI) external;

    //Mint nft (unreveal only) for some user by contact owner. use for bleeding or mint NFT from App
    function mintNFTsFor(address addr,uint256 amount) external;

    //Mint nft for some user by contact owner. use for bleeding or mint NFT from App
    function mintNFTFor(address addr,string memory tokenURI) external;

    //Mint nft for some user by contact owner. use for bleeding or mint NFT from App
    function burnNFTFor(address addr,uint256 tokenId) external;

    //Update display name of token when unreveal.
    function getUnrevealName() external view returns (string memory);

    //Update token uri of token when unreveal.
    function getUnrevealTokenUri() external view returns (string memory);

    function getUnrevealMetadata() external view returns (string memory,string memory);    
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface ITokenOperatableTemplate {
    
    function get_name() external view returns (string memory);

    function get_description() external view returns (string memory);

    function get_template_metadata(uint256 template_id) external view returns (string memory,string memory,uint256,bool,address);

    function is_template_defined(uint256 template_id) external view returns (bool);

    function is_template_enabled(uint256 template_id) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;


import "@openzeppelin/contracts/access/Ownable2Step.sol";
import "@openzeppelin/contracts/utils/math/Math.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "../Interfaces/ITokenOperatableTemplate.sol";
import "../Interfaces/IOperatableERC1155Token.sol";
import "../Interfaces/IOperatableERC721Token.sol";

abstract contract TokenOperatableTemplateContract is Ownable2Step,ITokenOperatableTemplate {
    using Math for uint256;
    using ERC165Checker for address;

    string private name;
    string private description;

    mapping(uint256 => string) private template_names;
    mapping(uint256 => string) private template_descs;
    mapping(uint256 => uint256) private operation_prices;
    mapping(uint256 => bool) private template_enabled;

    //For some reason in marketing we have template specific merchant if not set just use merchant address.
    mapping(uint256 => address) private template_merchants;
    mapping(uint256 => address) private template_currencies;

    address private merchant_address;
    address private currency_address = address(0);

    mapping(address => bool) private _operators;

    error OperatorAccount(address account);

    constructor(string memory name_,string memory description_) 
        Ownable(msg.sender)
    {
        name = name_;
        description = description_;
        merchant_address = msg.sender;
    }
    event OnTemplateUndefined(uint256 template_id);

    function set_currency(address addr) external onlyOperator {
        require(addr == address(0) || addr.supportsInterface(type(IERC20).interfaceId),"UNSUPPORT_CURRENCY");
        currency_address = addr;
    }
    function set_merchant(address merchant) external onlyOperator {
        require((merchant_address != merchant) && (merchant != address(0)),"INVALID_MERCHANT");
        merchant_address = merchant;
    }
    function get_last_template_id() public view virtual returns (uint256) {return 0;}
    function get_currency_address(uint256 template_id) public view returns (address){
        address addr = template_currencies[template_id];
        return addr != address(0) ? addr : currency_address;
    }
    function get_merchant_address(uint256 template_id) public view returns(address){
       address addr = template_merchants[template_id];
       return addr != address(0) ? addr : merchant_address;
    }

    function undefine_templates(uint256[] memory template_ids) external onlyOperator {
         for(uint256 i = 0; i < template_ids.length; i++)
           _undefine_template(template_ids[i]);    
    }
    function update_template_names(uint256[] memory template_ids,string[] memory template_names_) external onlyOperator {
        require(template_ids.length == template_names_.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _udpate_template_name(template_ids[i],template_names_[i]);    
    }
    function update_template_descs(uint256[] memory template_ids,string[] memory descs) external onlyOperator {
        require(template_ids.length == descs.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _update_template_desc(template_ids[i],descs[i]);    
    }
    function update_operation_prices(uint256[] memory template_ids,uint256[] memory prices) external onlyOperator {
        require(template_ids.length == prices.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _update_operation_price(template_ids[i],prices[i]);    
    }
    function update_template_merchants(uint256[] memory template_ids,address[] memory merchants) external onlyOperator {
        require(template_ids.length == merchants.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _update_template_merchant(template_ids[i],merchants[i]);    
    }
    function update_template_currencies(uint256[] memory template_ids,address[] memory currencies) external onlyOperator {
        require(template_ids.length == currencies.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _update_template_currency(template_ids[i],currencies[i]);    
    }
    function enable_templates(uint256[] memory template_ids,bool[] memory enables) external onlyOperator {
        require(template_ids.length == enables.length,"PARAM_DIM_MISMATCH");
        for(uint256 i = 0; i < template_ids.length; i++)
           _enable_template(template_ids[i],enables[i]);
    }

    function is_defined(uint256 template_id) public view returns(bool) {return (bytes(template_names[template_id]).length > 0);}
   
    function is_enabled(uint256 template_id) public view returns(bool) {return template_enabled[template_id];}
    
    function _undefine_template(uint256 template_id) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");
        _clear_template_metadata(template_id);
        onUndefineTemplate(template_id);
        emit OnTemplateUndefined(template_id);
    }
    function _fill_template_metadata(uint256 template_id,string memory name_,string memory desc,uint256 op_price,bool start_enabled,address merchant,address currency) internal{
        template_names[template_id] = name_;
        template_descs[template_id] = desc;
        operation_prices[template_id] = op_price;
        template_enabled[template_id] = start_enabled;
        template_merchants[template_id] = merchant;
        template_currencies[template_id] = currency;
    }
    function _clear_template_metadata(uint256 template_id) internal{
        delete template_names[template_id];
        delete template_descs[template_id];
        delete operation_prices[template_id];
        delete template_enabled[template_id];
        delete template_merchants[template_id];
        delete template_currencies[template_id];
    }
    function _udpate_template_name(uint256 template_id,string memory name_) internal{
        require(bytes(template_names[template_id]).length > 0,"NO_TPL_DEFINED");        
        require(bytes(name_).length > 0,"NO_TPL_NAME");        
        template_names[template_id] = name_;
    }
    function _update_template_desc(uint256 template_id,string memory desc) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");        
        template_descs[template_id] = desc;
    }
    function _update_operation_price(uint256 template_id,uint256 price) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");        
        operation_prices[template_id] = price;
    }
    function _update_template_merchant(uint256 template_id,address merchant) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");
        require(merchant != address(0),"NULL_ADDRESS");
        template_merchants[template_id] = merchant;
    }
    function _update_template_currency(uint256 template_id,address currency) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");
        require(currency != address(0),"NULL_ADDRESS");
        template_currencies[template_id] = currency;
    }
    function _enable_template(uint256 template_id,bool enabled) internal {
        require(is_defined(template_id),"NO_TPL_DEFINED");        
        template_enabled[template_id] = enabled;
    }
    function consume_operation_cost(uint256 template_id,uint256 applyCount) internal {
        require(applyCount > 0,"ZERO_APPLYCOUNT");
        uint256 op_price = operation_prices[template_id];
        if(op_price == 0)
            return;

        address _merchant_addr = get_merchant_address(template_id);
        require(_merchant_addr != address(0),"NO_MERCHANT_ADDR");

       (bool total_op_cost_result,uint256 total_op_cost) = op_price.tryMul(applyCount);
       require(total_op_cost_result,"OP_COST_OVERFLOW");
        
         address _currency_addr = get_currency_address(template_id);
        if(_currency_addr != address(0)){
           uint256 available_balance = IERC20(_currency_addr).balanceOf(msg.sender);
           require(available_balance >= total_op_cost,"UNSUFFICIENT_BALANCE");
           IERC20(_currency_addr).transferFrom(msg.sender, _merchant_addr, total_op_cost);
           if(msg.value > 0)
              payable(msg.sender).transfer(msg.value);
        }
        else{
            require(msg.value >= total_op_cost,"UNSUFFICIENT_BALANCE");
            uint256 remain_value = msg.value - total_op_cost;
            payable(_merchant_addr).transfer(total_op_cost);
            payable(msg.sender).transfer(remain_value);
        }
    }
    function isTemplateValid(uint256) internal virtual returns (bool) {return false;}
    function onUndefineTemplate(uint256) internal virtual {}

    function get_template_metadata(uint256 template_id) external view virtual override returns (string memory,string memory,uint256,bool,address){
        return (template_names[template_id],template_descs[template_id],operation_prices[template_id],template_enabled[template_id],get_merchant_address(template_id));
    }
    function is_template_defined(uint256 template_id) external view virtual override returns (bool){return is_defined(template_id);}

    function is_template_enabled(uint256 template_id) external view virtual override returns (bool){return template_enabled[template_id];}

    function get_name() external view virtual override returns (string memory){return name;}

    function get_description() external view virtual override returns (string memory){return description;}

    function set_operator(address addr,bool set) external virtual onlyOwner {
        require(addr != address(0),"Null Address allowed");
        _operators[addr] = set;
    }
    function as_operator(address addr) public view virtual returns(bool) {
        return _operators[addr];
    }

    modifier onlyOperator() {
        _checkIsOperator();
        _;
    }
    function _check_operator(address addr) internal view virtual returns(bool) {
        return _operators[addr];
    }
    function _checkIsOperator() internal view virtual {
        address _sender = _msgSender();
        if ((owner() != _sender) && (!_check_operator(_sender))) {
            revert OperatorAccount(_sender);
        }
    }

    function _is_operatable_erc1155(address addr) internal view returns(bool) {
       return (addr != address(0)) && addr.supportsInterface(type(IOperatableERC1155Token).interfaceId);
    }
    function _is_operatable_erc721(address addr) internal view returns (bool){
        return (addr != address(0)) && addr.supportsInterface(type(IOperatableERC721Token).interfaceId);
    }
}